# Maintainer: Allan McRae <allan@archlinux.org>

pkgname=abs
pkgver=2.3.3
pkgrel=1
pkgdesc="Utilities to download and work with the Arch Build System (ABS)"
arch=('any')
url="http://projects.archlinux.org/git/?p=abs.git"
license=('GPL')
depends=('bash' 'rsync')
backup=('etc/abs.conf')
install="$pkgname.install"
source=("ftp://ftp.archlinux.org/other/abs/${pkgname}-${pkgver}.tar.gz")
md5sums=('a65e55d96118532e1138ff107ac7f489')

build() {
  cd $srcdir/$pkgname
  
  make CONFDIR=/etc/ || return 1
}

package() {
  cd $srcdir/$pkgname
  
  make CONFDIR=/etc/ DESTDIR=${pkgdir} install || return 1
  
  # Add readme file, and make base /var/abs path
  install -dm755 ${pkgdir}/var/abs/local/
  install -Dm644 ${srcdir}/abs/README ${pkgdir}/var/abs/README
  
  # cleanup stuff we don't need
  rm -Rf $pkgdir/usr/share/

  # change ABS tags for x86_64 to correct values
  if [ "$CARCH" = "x86_64" ]; then
    sed \
      -e 's|"i686"|"x86_64"|g' \
      -e 's|"rsync.archlinux.org"|"abs.archserver.org"|g' \
      -e 's|core extra community testing|base lamp webapps !testing|g' \
      -i ${pkgdir}/etc/abs.conf
  fi
}

# vim:set ts=2 sw=2 et:
