pkgname=aufs2
pkgver=2.6.31_20090910
pkgrel=2
_kernver=${pkgver%_*}-ARCHSERV
pkgdesc="Another Unionfs Implementation"
arch=('i686' 'x86_64')
url="http://aufs.sourceforge.net/"
license=('GPL2')
depends=('kernel26>=2.6.31' 'kernel26<2.6.32')
replaces=('aufs')
options=(!makeflags)
install="${pkgname}.install"
source=("ftp://ftp.archlinux.org/other/aufs2/${pkgname}-${pkgver}.tar.bz2")
md5sums=('90af4ef41dcd68ba1171a2c562864c7c')

build() {
  cd ${srcdir}/${pkgname}-${pkgver} || return 1
  
  sed -e 's|CONFIG_AUFS_HINOTIFY =.*|CONFIG_AUFS_HINOTIFY = y|' \
    -i config.mk || return 1
  sed -e 's|CONFIG_AUFS_EXPORT =.*|CONFIG_AUFS_EXPORT = y|' \
    -i config.mk || return 1
  sed -e 's|CONFIG_AUFS_SHWH =.*|CONFIG_AUFS_SHWH = y|' \
    -i config.mk || return 1
  sed -e 's|CONFIG_AUFS_BDEV_LOOP =.*|CONFIG_AUFS_BDEV_LOOP = y|' \
    -i config.mk || return 1
  sed -e 's|CONFIG_AUFS_BR_RAMFS =.*|CONFIG_AUFS_BR_RAMFS = y|' \
    -i config.mk || return 1
  sed -e 's|CONFIG_AUFS_DEBUG =.*|CONFIG_AUFS_DEBUG =|' \
    -i config.mk || return 1
  
  if [ "${CARCH}" = "x86_64" ]; then
    inot64=" y"
  else
    inot64=""
  fi
  sed -e "s|CONFIG_AUFS_INO_T_64 =.*|CONFIG_AUFS_INO_T_64 =${inot64}|" \
     -i config.mk || return 1
  
  # build
  make KDIR=/usr/src/linux-${_kernver} || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver} || return 1
  
  # install
  install -D -m644 fs/aufs/aufs.ko $pkgdir/lib/modules/${_kernver}/kernel/fs/aufs/aufs.ko || return 1
  # tweak the install script for the right kernel version
  sed -e "s/KERNEL_VERSION=.*/KERNEL_VERSION=${_kernver}/g" \
    -i $startdir/$pkgname.install || return 1
  
  # install include files
  install -D -m 644 include/linux/aufs_type.h $pkgdir/usr/src/linux-$_kernver/include/linux/aufs_type.h || return 1
} 

# vim:set ts=2 sw=2 et:
