# Maintainer: Andreas Radke <andyrtr at archlinux.org>

pkgname=kernel26-lts
_kernelname=${pkgname#kernel26}
_basekernel=2.6.27
pkgver=${_basekernel}.38
pkgrel=2
pkgdesc="The Linux Kernel and modules - stable longtime supported kernel package suitable for servers"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://www.kernel.org"
backup=(etc/mkinitcpio.d/${pkgname}.preset)
depends=('coreutils' 'kernel26-firmware>=2.6.27' 'module-init-tools' 'mkinitcpio>=0.5.20')
install=${pkgname}.install
source=("ftp://ftp.kernel.org/pub/linux/kernel/v2.6/linux-$_basekernel.tar.bz2"
        "ftp://ftp.kernel.org/pub/linux/kernel/v2.6/patch-$pkgver.bz2"
        'config.i686'
        'config.x86_64'
        "${pkgname}.preset"
      	# ext4 patches from Fedora
      	#http://cvs.fedoraproject.org/viewvc/rpms/kernel/F-10/?pathrev=kernel-2_6_27_29-170_2_79_fc10
      	'linux-2.6.27-ext4-rename-ext4dev-to-ext4.patch'
      	'linux-2.6.27.9-ext4-cap-check-delay.patch'
        'archserver-bootlogo_clut224.ppm')
md5sums=('b3e78977aa79d3754cb7f8143d7ddabd'
         '80217587b03706705c4c0c393c1c01b5'
         '07358c523d113236cec144ce30863d96'
         '280899021f2f3dd3d7aef95769d55c53'
         'a13338958d1b241f8dfd4c6014cad3d4'
         '659953c9c437d311bf93eff505ef8e67'
         '8cd12e9727d9221aacfa52ad9b9a42f9'
         '3ea7105d492b69eed38402c4716bd9fe')

build() {
  KARCH=x86
  
  cd ${srcdir}/linux-$_basekernel
   if [ "$_basekernel" != "$pkgver" ]; then
     # add latest kernel stable patch
     patch -Np1 -i ${srcdir}/patch-$pkgver || return 1
   fi

  # add full ext4 support
  patch -Np1 -i ${srcdir}/linux-2.6.27-ext4-rename-ext4dev-to-ext4.patch || return 1
  patch -Np1 -i ${srcdir}/linux-2.6.27.9-ext4-cap-check-delay.patch || return 1
  
  # Custom boot logo
  cp $srcdir/archserver-bootlogo_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm

  case "$CARCH" in
    "x86_64")
    cat $srcdir/config.x86_64 > ./.config || return 1
    ;;
    "i686")
    cat $srcdir/config.i686 > ./.config || return 1
    ;;
  esac
  if [ "${_kernelname}" != "" ]; then
    sed -i "s|CONFIG_LOCALVERSION=.*|CONFIG_LOCALVERSION=\"${_kernelname}\"|g" ./.config || return 1
  fi
  
  # get kernel version  
  make prepare
  _kernver="$(make kernelrelease)"
  
  # load configuration
  ####################
  yes "" | make config
  
  # build!
  make bzImage modules
}

package() {
  KARCH=x86

  cd ${srcdir}/linux-$_basekernel

  mkdir -p ${pkgdir}/{lib/modules,boot} || return 1
  make INSTALL_MOD_PATH=${pkgdir} modules_install || return 1
  cp System.map ${pkgdir}/boot/System.map26${_kernelname} || return 1
  cp arch/$KARCH/boot/bzImage ${pkgdir}/boot/vmlinuz26${_kernelname} || return 1
  install -Dm644 Makefile ${pkgdir}/usr/src/linux-${_kernver}/Makefile || return 1
  install -Dm644 kernel/Makefile ${pkgdir}/usr/src/linux-${_kernver}/kernel/Makefile || return 1
  install -Dm644 .config ${pkgdir}/usr/src/linux-${_kernver}/.config || return 1
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/include || return 1
  
  for i in acpi asm-{generic,x86} config linux math-emu media net pcmcia scsi sound video; do
    cp -a include/$i ${pkgdir}/usr/src/linux-${_kernver}/include/ || return 1
  done
  
  # copy files necessary for later builds, like nvidia and vmware
  cp Module.symvers ${pkgdir}/usr/src/linux-${_kernver} || return 1
  cp -a scripts ${pkgdir}/usr/src/linux-${_kernver} || return 1
  # fix permissions on scripts dir
  chmod og-w -R ${pkgdir}/usr/src/linux-${_kernver}/scripts || return 1
  #mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/.tmp_versions
  
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/kernel || return 1
  
  cp arch/$KARCH/Makefile ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/ || return 1
  if [ "$CARCH" = "i686" ]; then
    cp arch/$KARCH/Makefile_32.cpu ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/ || return 1
  fi
  cp arch/$KARCH/kernel/asm-offsets.s ${pkgdir}/usr/src/linux-${_kernver}/arch/$KARCH/kernel/ || return 1
  
  # add headers for lirc package
  #mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video
  #cp drivers/media/video/*.h  ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video/
  #for i in bt8xx cpia2 cx25840 cx88 em28xx et61x251 pwc saa7134 sn9c102 usbvideo zc0301; do
  #  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video/$i
  #  cp -a drivers/media/video/$i/*.h ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/video/$i
  #done
  
  # add docbook makefile
  install -Dm644 Documentation/DocBook/Makefile ${pkgdir}/usr/src/linux-${_kernver}/Documentation/DocBook/Makefile || return 1
  
  # add dm headers
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/md || return 1
  cp drivers/md/*.h  ${pkgdir}/usr/src/linux-${_kernver}/drivers/md || return 1
  
  # add inotify.h
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/include/linux || return 1
  cp include/linux/inotify.h ${pkgdir}/usr/src/linux-${_kernver}/include/linux/ || return 1
  
  # add wireless headers
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/net/mac80211/ || return 1
  cp net/mac80211/*.h ${pkgdir}/usr/src/linux-${_kernver}/net/mac80211/ || return 1
  
  # add dvb headers for external modules
  # in reference to:
  # http://bugs.archlinux.org/task/9912
  #mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/dvb/dvb-core
  #cp drivers/media/dvb/dvb-core/*.h ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/dvb/dvb-core/
  
  # add dvb headers for external modules
  # in reference to:
  # http://bugs.archlinux.org/task/11194
  #mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/include/config/dvb/
  #cp include/config/dvb/*.h ${pkgdir}/usr/src/linux-${_kernver}/include/config/dvb/
  
  # add dvb headers for http://mcentral.de/hg/~mrec/em28xx-new
  # in reference to:
  # http://bugs.archlinux.org/task/13146
  #mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/dvb/frontends/
  #cp drivers/media/dvb/frontends/lgdt330x.h ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/dvb/frontends/
  #cp drivers/media/video/msp3400-driver.h ${pkgdir}/usr/src/linux-${_kernver}/drivers/media/dvb/frontends/
  
  # add xfs and shmem for aufs building
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/fs/xfs || return 1
  mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/mm || return 1
  cp fs/xfs/xfs_sb.h ${pkgdir}/usr/src/linux-${_kernver}/fs/xfs/xfs_sb.h || return 1
  
  # add headers for virtualbox
  # in reference to:
  # http://bugs.archlinux.org/task/14568
  cp -a include/drm $pkgdir/usr/src/linux-${_kernver}/include/ || return 1
  
  # add vmlinux
  cp vmlinux ${pkgdir}/usr/src/linux-${_kernver} || return 1
  
  # copy in Kconfig files
  for i in `find . -name "Kconfig*"`; do 
    mkdir -p ${pkgdir}/usr/src/linux-${_kernver}/`echo $i | sed 's|/Kconfig.*||'` || return 1
    cp $i ${pkgdir}/usr/src/linux-${_kernver}/$i || return 1
  done
  
  cd ${pkgdir}/usr/src/linux-${_kernver}/include && ln -s asm-$KARCH asm || return 1
  
  chown -R root:root ${pkgdir}/usr/src/linux-${_kernver} || return 1
  find ${pkgdir}/usr/src/linux-${_kernver} -type d -exec chmod 755 {} \; || return 1
  cd ${pkgdir}/lib/modules/${_kernver} && (rm -f source build; ln -sf ../../../usr/src/linux-${_kernver} build) || return 1
  
  # install fallback mkinitcpio.conf file and preset file for kernel
  install -Dm644 ${srcdir}/${pkgname}.preset ${pkgdir}/etc/mkinitcpio.d/${pkgname}.preset || return 1
  
  # set correct depmod command for install
  sed \
    -e  "s/KERNEL_NAME=.*/KERNEL_NAME=${_kernelname}/g" \
    -e  "s/KERNEL_VERSION=.*/KERNEL_VERSION=${_kernver}/g" \
    -i $startdir/${pkgname}.install || return 1
  sed \
    -e "s|source .*|source /etc/mkinitcpio.d/kernel26${_kernelname}.kver|g" \
    -e "s|default_image=.*|default_image=\"/boot/${pkgname}.img\"|g" \
    -e "s|fallback_image=.*|fallback_image=\"/boot/${pkgname}-fallback.img\"|g" \
    -i ${pkgdir}/etc/mkinitcpio.d/${pkgname}.preset || return 1

  echo -e "# DO NOT EDIT THIS FILE\nALL_kver='${_kernver}'" > ${startdir}/pkg/etc/mkinitcpio.d/${pkgname}.kver || return 1
  
  # remove unneeded architectures
  rm -rf ${pkgdir}/usr/src/linux-${_kernver}/arch/{alpha,arm,arm26,avr32,blackfin,cris,frv,h8300,ia64,m32r,m68k,m68knommu,mips,microblaze,mn10300,parisc,powerpc,ppc,s390,sh,sh64,sparc,sparc64,um,v850,xtensa} || return 1
  
  # remove the firmware
  rm -rf ${pkgdir}/lib/firmware || return 1
}

# vim:set ts=2 sw=2 et:
